Autore Topic: Backup compresso del profilo di Firefox  (Letto 1472 volte)

0 Utenti e 1 Visitatore stanno visualizzando questo topic.

Offline Savoldo

  • Newbie
  • *
  • Post: 16
  • Karma: 10
Backup compresso del profilo di Firefox
« il: 02/05/2012, 04:59 »
Vi propongo una procedura automatizzata che fa il backup del profilo di Firefox.
Strumento indispensabile, il compressore 7-Zip, gratuito che trovate al link http://www.7-zip.org/

Ho trovato un bug: quando costruisco il timbro orario da appendere al nome del file, se l'ora corrente ha lo 0 davanti tronca l'orario. Questo è il codice fissato.

Codice: [Seleziona]
:: Nome script     BkpFirefox.cmd
:: Autore          Marco Anelli
:: Data            01/05/2012
:: Ultima modifica 22/05/2012
:: Comportamento   Backup compresso con 7Zip del profilo di Firefox
:: Compatibilità   XP, Vista, 7


@echo off
cls
title Backup compresso di Firefox
echo.
echo.
echo                     BACKUP COMPRESSO DEL PROFILO DI FIREFOX
echo                     ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
echo.
echo.
echo Procedura di backup compresso delle
echo impostazioni di Firefox.
echo Strumento: 7-Zip
echo Testato su Firefox 9.0 - 12.0
echo.

SetLocal ENABLEEXTENSIONS

:: Dichiarazione variabili
SET COMPRESSORE=%ProgramFiles%\7-Zip\7z.exe
SET FIREFOX=%ProgramFiles%\Mozilla Firefox\firefox.exe
SET SOURCE_DIR_FIREFOX=%APPDATA%\Mozilla\Firefox\Profiles
SET TARGET_DIR_FIREFOX=Z:
SET ARCHIVIO=Firefox-all
SET DATA=%date:~6,4%%date:~3,2%%date:~0,2%
set ORA=%time:~0,2%
if %ORA% leq 9 (goto am) else (goto pm)
:am
set ORARIO=0%time:~1,1%%time:~3,2%%time:~6,2%
goto continua
:pm
SET ORARIO=%time:~0,2%%time:~3,2%%time:~6,2%
goto continua

:continua
echo Lista variabili:
echo ----------------
echo.
echo Eseguibile compressore: [%COMPRESSORE%]
echo Eseguibile Firefox: [%FIREFOX%]
echo Directory sorgente: [%SOURCE_DIR_FIREFOX%]
echo Directory target: [%TARGET_DIR_FIREFOX%]
echo Nome archivio: [%ARCHIVIO%]
echo Timbro data/ora: [%DATA%%ORARIO%]
echo.
echo.
echo Nota: per cambiare i valori delle variabili devi editare lo script.
echo.
echo              *** FIREFOX DEVE ESSERE CHIUSO ***
echo.
set /p choice=Continuare con la procedura oppure esci (S/N)?:
if "%choice%"=="s" goto proseguo
if "%choice%"=="S" goto proseguo
if "%choice%"=="n" goto annulla
if "%choice%"=="N" goto annulla
:proseguo

tasklist | find /i "firefox.exe"
if %errorlevel% equ 0 (goto in_esecuzione) else (goto compressore)

:compressore
IF EXIST "%COMPRESSORE%" (goto firefox) else (goto no_compressore)
:no_compressore
title Prompt dei comandi
echo.
echo ATTENZIONE: Il programma di compressione non esiste.
echo.
goto eof

:firefox
IF EXIST "%Firefox%" (goto destdir) else (goto no_firefox)
:no_firefox
title Prompt dei comandi
echo.
echo ATTENZIONE: Il programma Firefox non esiste.
echo.
goto eof

:destdir
IF EXIST %TARGET_DIR_FIREFOX% (goto crea_archivio) else (goto no_destdir)
:no_destdir
title Prompt dei comandi
echo.
echo ATTENZIONE: Il percorso di destinazione non esiste.
echo.
goto eof

:crea_archivio
title Archiviazione profilo Firefox
"%COMPRESSORE%" a -tzip -r -mx5 %TARGET_DIR_FIREFOX%\%ARCHIVIO%-%DATA%%ORARIO%.zip "%SOURCE_DIR_FIREFOX%\"
if %errorlevel% equ 0 (goto successo) else (goto errore)
:successo
echo.
echo L'archivio e' stato creato con successo.
echo.
goto eof

:in_esecuzione
title Prompt dei comandi
echo.
echo ATTENZIONE: Firefox e' in esecuzione.
echo.
goto eof

:annulla
cls
echo.
title Prompt dei comandi
echo Operazione annullata dall'utente.
echo.
goto eof

:eof
title Prompt dei comandi
:: Elimino le variabili
SET COMPRESSORE=
SET Firefox=
SET SOURCE_DIR_FIREFOX=
SET TARGET_DIR_FIREFOX=
SET ARCHIVIO=
SET DATA=
SET ORARIO=
SET ORA=
ENDLOCAL
echo Fine
« Ultima modifica: 27/05/2012, 06:17 da Savoldo »